SendMessageBox.qml
View Options

	/*
	* This file is part of kazv.
	* SPDX-FileCopyrightText: 2020-2023 tusooa <tusooa@kazv.moe>
	* SPDX-License-Identifier: AGPL-3.0-or-later
	*/

	import QtQuick 2.15
	import QtQuick.Layouts 1.15
	import QtQuick.Controls 2.15
	import QtQuick.Dialogs 1.3

	import org.kde.kirigami 2.13 as Kirigami
	import moe.kazv.mxc.kazv 0.0 as MK

	import '.' as Kazv

	ColumnLayout {
	id: sendMessageBox
	property var room
	property var draftReplyTo: ''
	property var timeline: room.timeline()

	onRoomChanged: {
	textArea.changeText(room.localDraft, true);
	}

	RowLayout {
	visible: !!sendMessageBox.draftReplyTo
	spacing: 0

	Rectangle {
	color: '#10000000'
	Layout.leftMargin: Kirigami.Units.largeSpacing
	Layout.fillWidth: true
	Layout.preferredHeight: replyLabel.height + replyItem.height + Kirigami.Units.largeSpacing
	ColumnLayout {
	anchors.fill: parent
	spacing: 0

	Label {
	id: replyLabel
	Layout.leftMargin: Kirigami.Units.largeSpacing
	Layout.topMargin: Kirigami.Units.largeSpacing
	Layout.fillWidth: true
	text: l10n.get('send-message-box-reply-to')
	}

	Item {
	id: replyItem
	Layout.leftMargin: Kirigami.Units.largeSpacing
	Layout.minimumHeight: Math.min(replyToEventView.implicitHeight, Kirigami.Units.gridUnit * 5)
	Layout.maximumHeight: Kirigami.Units.gridUnit * 5
	Layout.fillWidth: true
	clip: true

	Kazv.EventViewWrapper {
	id: replyToEventView
	anchors {
	top: parent.top
	left: parent.left
	right: parent.right
	}
	event: room.messageById(sendMessageBox.draftReplyTo)
	compactMode: true
	}
	}
	}
	}
	ToolButton {
	Layout.alignment: Qt.AlignTop
	Layout.rightMargin: Kirigami.Units.largeSpacing
	action: removeReplyToAction
	display: AbstractButton.IconOnly
	}
	}

	RowLayout {
	TextArea {
	id: textArea
	objectName: 'draftMessage'
	property var shortcutList: ["Ctrl+Return", "Ctrl+Enter"]
	property var inhibitTyping: false
	placeholderText: l10n.get('send-message-box-input-placeholder')
	Layout.fillWidth: true
	wrapMode: TextEdit.Wrap
	onTextChanged: {
	room.setLocalDraft(text);
	if (!inhibitTyping) {
	room.setTyping(true);
	}
	inhibitTyping = false;
	}

	function changeText(newText, inhibitTyping) {
	textArea.inhibitTyping = inhibitTyping;
	textArea.text = newText;
	}

	onVisibleChanged: {
	if (!visible) {
	room.updateLocalDraftNow();
	}
	}

	// Shortcut keys for sending messages (TODO: Shortcut keys customized by the user)
	Shortcut {
	sequences: textArea.shortcutList
	onActivated: {
	sendAction.trigger()
	}
	}

	DropArea {
	anchors.fill: parent
	onDropped: (drag) => {
	if (drag.hasUrls) {
	confirmUploadPopup.call(drag.urls);
	}
	}
	}
	}

	ToolButton {
	icon.name: "document-send-symbolic"
	onClicked: sendMediaFileAction.trigger()
	}

	ToolButton {
	action: stickersAction
	display: AbstractButton.IconOnly
	}

	ToolButton {
	icon.name: "document-send"
	onClicked: sendAction.trigger()
	}
	}

	function mentionUser(userId) {
	const prefix = textArea.text.slice(0, textArea.cursorPosition);
	const suffix = textArea.text.slice(textArea.cursorPosition);
	let insertion = userId;
	// If we are not at the beginning and the prev char is not a space,
	// insert a space there.
	if (prefix && prefix.slice(prefix.length - 1).trim() !== '') {
	insertion = ' ' + insertion;
	}
	// If we are at the end or the next char is not a space,
	// insert a space there.
	if (!suffix \|\| suffix.slice(0, 1).trim() !== '') {
	insertion = insertion + ' ';
	}
	textArea.text = prefix + insertion + suffix;
	textArea.cursorPosition = prefix.length + insertion.length;
	}

	function focusInput() {
	textArea.forceActiveFocus();
	}

	Kirigami.Action {
	id: removeReplyToAction
	iconName: 'window-close-symbolic'
	text: l10n.get('send-message-box-remove-reply-to-action')
	onTriggered: {
	sendMessageBox.draftReplyTo = '';
	}
	}

	Kirigami.Action {
	id: sendAction
	iconName: "document-send"
	text: l10n.get("send-message-box-send")
	onTriggered: {
	room.setTyping(false);
	room.sendTextMessage(textArea.text, draftReplyTo);
	textArea.changeText("", true);
	draftReplyTo = '';
	}
	}
	Kirigami.Action {
	id:sendMediaFileAction
	iconName: "mail-attachment-symbolic"
	text: l10n.get("send-message-box-send-file")
	onTriggered: {
	fileDialog.open()
	}
	}

	property var confirmUploadPopup: ConfirmUploadPopup {
	id: confirmUploadPopup
	onUploadRequested: (url) => {
	sendMessageBox.uploadFile(url);
	}
	}

	property var fileDialog: FileDialog {
	onAccepted: {
	sendMessageBox.uploadFile(fileUrl);
	}
	}

	function uploadFile(fileUrl) {
	kazvIOManager.startNewUploadJob(
	matrixSdk.serverUrl, fileUrl, matrixSdk.token,
	room.roomId, sdkVars.roomList, room.encrypted
	);
	}

	property var stickerPopup: Kirigami.OverlaySheet {
	id: stickerPopup
	title: l10n.get('send-message-box-stickers-popup-title')

	Kazv.StickerPicker {
	stickerPackList: matrixSdk.stickerPackList()
	onSendMessageRequested: eventJson => {
	console.log(JSON.stringify(eventJson));
	room.sendMessage(eventJson, draftReplyTo);
	draftReplyTo = '';
	stickerPopup.close();
	}
	}
	}

	Kirigami.Action {
	id: stickersAction
	iconName: 'smiley'
	text: l10n.get('send-message-box-stickers')
	onTriggered: stickerPopup.open()
	}
	}

File Metadata

Mime Type: text/plain
Expires: Sun, Dec 1, 2:21 PM (1 d, 14 h)
Storage Engine: blob
Storage Format: Raw Data
Storage Handle: 41721
Default Alt Text: SendMessageBox.qml (5 KB)

SendMessageBox.qml
No OneTemporary
Actions

SendMessageBox.qml
View Options

File Metadata

Event Timeline

SendMessageBox.qmlNo OneTemporaryActions

SendMessageBox.qmlView Options

File Metadata

Event Timeline

SendMessageBox.qml
No OneTemporary
Actions

SendMessageBox.qml
View Options