Page MenuHomePhorge
Files F7893303

KazvIOMenu.qml
No OneTemporary
Actions

Size
3 KB
Referenced Files
None
Subscribers
None

KazvIOMenu.qml
View Options

/*
* This file is part of kazv.
* SPDX-FileCopyrightText: 2022 nannanko <nannanko@kazv.moe>
* SPDX-License-Identifier: AGPL-3.0-or-later
*/
import QtQuick 2.15
import QtQuick.Controls 2.15
import QtQuick.Layouts 1.15
import org.kde.kirigami 2.13 as Kirigami
import moe.kazv.mxc.kazv 0.0 as MK
ColumnLayout {
id: kazvIOProgressBar
required property var kazvIOJob
property var jobId
property bool isUpload
visible: kazvIOJob ? true : false
onKazvIOJobChanged: {
if (kazvIOJob == null) {
return
}
if (kazvIOJob.isResulted()) {
jobSlots.onResult(kazvIOJob.error())
return
}
if (kazvIOJob.isSuspended()) {
pauseAction.suspended = true
}
}
Connections {
id: jobSlots
target: kazvIOJob
function onResult(ec) {
progressBarLayout.visible = false
resultMsgLayout.visible = true
let resultL10nId = isUpload ? 'kazv-io-upload-failure-prompt' : 'kazv-io-download-failure-prompt'
switch (ec) {
case MK.KazvIOBaseJob.NoError:
if (isUpload) {
return
}
resultMsg.text = l10n.get('kazv-io-download-success-prompt')
break
case MK.KazvIOBaseJob.UserCancel:
resultMsg.text = l10n.get(resultL10nId, {detail: l10n.get('kazv-io-failure-detail-user-cancel')})
break
case MK.KazvIOBaseJob.KIOError:
resultMsg.text = l10n.get(resultL10nId, {detail: l10n.get('kazv-io-failure-detail-network-error')})
break
case MK.KazvIOBaseJob.QtError:
resultMsg.text = l10n.get(resultL10nId, {detail: l10n.get('kazv-io-failure-detail-file-error')})
break
case MK.KazvIOBaseJob.KazvError:
resultMsg.text = l10n.get(resultL10nId, {detail: l10n.get('kazv-io-failure-detail-kazv-error')})
break
}
}
}
Label {
property string l10nId: isUpload ? 'kazv-io-uploading-prompt' : 'kazv-io-downloading-prompt'
text: kazvIOJob ? l10n.get(l10nId, {fileName: kazvIOJob.fileName()}) : ""
}
RowLayout {
id: progressBarLayout
visible: true
Layout.preferredWidth: parent.width
ProgressBar {
id: progressBar
Layout.fillWidth: true
value: kazvIOJob ? kazvIOJob.progress : 0
}
Kirigami.Action {
id: pauseAction
iconName: suspended ? "media-playback-start" : "media-playback-pause"
property var suspended: false
onTriggered: {
if (pauseAction.suspended) {
kazvIOJob.resume()
} else {
kazvIOJob.suspend()
}
suspended = !suspended
}
}
Kirigami.Action {
id: cancelAction
iconName: "dialog-cancel"
onTriggered: {
pauseAction.suspended = false
kazvIOJob.cancel()
}
}
RoundButton {
id: pauseBtn
Accessible.name: pauseAction.suspended ? l10n.get('kazv-io-resume') : l10n.get('kazv-io-pause')
icon.name: pauseAction.suspended ? "media-playback-start" : "media-playback-pause"
onClicked: pauseAction.trigger()
}
RoundButton {
icon.name: "dialog-cancel"
Accessible.name: l10n.get('kazv-io-cancel')
onClicked: cancelAction.trigger()
}
}
RowLayout {
id: resultMsgLayout
visible: false
Text {
id: resultMsg
}
Button {
text: l10n.get('kazv-io-prompt-close')
onClicked: {
if (isUpload) {
kazvIOManager.deleteUploadJob(jobId, kazvIOJob)
} else {
kazvIOManager.deleteDownloadJob(jobId)
resultMsgLayout.visible = false
progressBarLayout.visible = true
resultMsg.text = null
kazvIOJob = null
}
}
}
}
}

File Metadata

Mime Type
text/plain
Expires
Thu, Oct 2, 4:54 AM (19 h, 4 m)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
487352
Default Alt Text
KazvIOMenu.qml (3 KB)

Event Timeline