Page MenuHomePhorge
Files F2577360

Bubble.qml
No OneTemporary
Actions

Size
3 KB
Referenced Files
None
Subscribers
None

Bubble.qml
View Options

/*
* This file is part of kazv.
* SPDX-FileCopyrightText: 2020-2023 tusooa <tusooa@kazv.moe>
* SPDX-License-Identifier: AGPL-3.0-or-later
*/
import QtQuick 2.15
import QtQuick.Layouts 1.15
import QtQuick.Controls 2.15
import org.kde.kirigami 2.13 as Kirigami
import '.' as Kazv
ItemDelegate {
id: upper
default property var children
property var currentEvent: event
property var menuContent: []
readonly property var bubbleSpacing: leftPadding + rightPadding
Layout.fillWidth: true
Layout.preferredHeight: bubbleRootLayout.implicitHeight
property var backgroundItem: Rectangle {
anchors.fill: parent
color: hovered ? Kirigami.Theme.activeBackgroundColor : Kirigami.Theme.backgroundColor
}
background: compactMode ? null : backgroundItem
property var eventSourcePopup: Kirigami.OverlaySheet {
title: l10n.get('event-source-popup-title')
Kazv.EventSourceView {
event: upper.currentEvent
}
}
property var menu: Menu {
objectName: 'bubbleContextMenu'
property list<QtObject> staticItems: [
Kirigami.Action {
objectName: 'replyToMenuItem'
text: l10n.get('event-reply-action')
onTriggered: setDraftReplyTo(currentEvent.eventId)
enabled: event && !event.redacted
},
Kirigami.Action {
objectName: 'deleteMenuItem'
text: l10n.get('event-delete')
onTriggered: eventView.redactSelf()
enabled: event && !event.redacted
},
MenuSeparator {},
Kirigami.Action {
text: l10n.get('event-view-source')
onTriggered: eventSourcePopup.open()
}
]
contentData: Array.from(staticItems).concat(upper.menuContent)
}
function shouldPopupMenu() {
return !compactMode
}
function maybePopupMenu() {
if (shouldPopupMenu()) {
menu.popup(parent)
}
}
ColumnLayout {
id: bubbleRootLayout
anchors.left: parent.left
anchors.right: parent.right
property var inReplyTo: RowLayout {
Layout.fillWidth: true
Layout.margins: 0
Rectangle {
Layout.fillHeight: true
Layout.preferredWidth: Kirigami.Units.smallSpacing
color: Kirigami.Theme.activeTextColor
}
Loader {
id: inReplyToLoader
source: 'qrc:/EventViewCompact.qml'
active: currentEvent.replyingToEventId && !compactMode
asynchronous: true
Layout.minimumHeight: inReplyToLoader.item ? inReplyToLoader.item.height : 0
Layout.fillWidth: true
property var event: room.messageById(currentEvent.replyingToEventId)
property var props: ({
event,
sender: room.member(event.sender || matrixSdk.userId),
stateKeyUser: event.stateKey ? room.member(event.stateKey) : {},
isGapped: timeline.gaps.includes(event.eventId),
})
}
}
property var eventContent: RowLayout {
Layout.fillWidth: true
property var encryptedIcon: Kirigami.Icon {
source: 'emblem-encrypted-locked'
Layout.preferredHeight: inlineBadgeSize
Layout.preferredWidth: inlineBadgeSize
}
property var moreButton: ToolButton {
id: moreButton
action: popupAction
display: AbstractButton.IconOnly
}
data: [
...(event && event.encrypted ? [encryptedIcon] : []),
...(Array.isArray(upper.children) ? upper.children :
upper.children ? [upper.children] : []),
...(!compactMode ? [moreButton] : []),
]
}
property var popupAction: Kirigami.Action {
id: popupAction
text: l10n.get('event-popup-action')
iconName: 'view-more-horizontal-symbolic'
onTriggered: maybePopupMenu()
}
children: event.replyingToEventId && !compactMode ? [inReplyTo, eventContent] : [eventContent];
}
}

File Metadata

Mime Type
text/plain
Expires
Tue, Jun 24, 6:01 AM (8 h, 51 m)
Storage Engine
blob
Storage Format
Raw Data
Storage Handle
234712
Default Alt Text
Bubble.qml (3 KB)

Event Timeline