main.qml
No OneTemporary
Actions

Size

6 KB

Referenced Files

None

Subscribers

None

main.qml
View Options

	/*
	* This file is part of kazv.
	* SPDX-FileCopyrightText: 2020-2023 tusooa <tusooa@kazv.moe>
	* SPDX-License-Identifier: AGPL-3.0-or-later
	*/

	import QtQuick 2.1
	import org.kde.kirigami 2.4 as Kirigami
	import QtQuick.Controls 2.0 as Controls
	import moe.kazv.mxc.kazv 0.0 as MK

	import '.' as Kazv
	import 'shortcuts' as KazvShortcuts

	import 'l10n.js' as L10n

	Kirigami.ApplicationWindow {
	id: root

	property var kazvIOManager: MK.KazvIOManager {
	cacheDirectory: kazvConfig.cacheDirectory
	}

	property var matrixSdk: MK.MatrixSdk {
	onLoginSuccessful: {
	switchToMainPage();
	recordLastSession();
	}
	onLoginFailed: {
	console.log("Login Failed");
	showPassiveNotification(l10n.get('login-page-request-failed-prompt', { errorCode, errorMsg }));
	}
	onDiscoverFailed: {
	console.log("Discover Failed");
	showPassiveNotification(l10n.get('login-page-discover-failed-prompt', { errorCode, errorMsg }));
	}
	onSessionChanged: {
	console.log('session changed');
	reloadSdkVariables();
	}
	}

	property var loggedIn: !!matrixSdk.token

	property var sdkVars: QtObject {
	property var roomList: matrixSdk.roomList()
	property string currentRoomId: ''
	}

	property var l10nProvider: MK.L10nProvider {
	}

	property var kazvConfig: MK.KazvConfig {
	}

	function initializeL10n () {
	const availableLocales = l10nProvider.availableLocaleCodes();
	console.log('available locales:', availableLocales);
	const desiredLanguages = [Qt.uiLanguage];
	console.log('ui language is: ', desiredLanguages);
	const defaultLocale = 'en';

	const wantedLocales = L10n.negotiateLanguages(desiredLanguages, availableLocales, defaultLocale);

	console.log('wanted locales:', wantedLocales);

	const bundles = L10n.generateBundles(wantedLocales, l10nProvider.getFtlData(wantedLocales));
	const provider = new L10n.FluentProvider(bundles);

	return provider;
	}

	property var l10n: initializeL10n();

	title: l10n.get('app-title')

	globalDrawer: Kirigami.GlobalDrawer {
	title: l10n.get('global-drawer-title')
	titleIcon: "applications-graphics"
	property var actionGroupName: 'global-drawer-actions'
	actions: [
	Kirigami.Action {
	objectName: 'switch-account'
	text: l10n.get('global-drawer-action-switch-account')
	iconName: 'system-switch-user'
	onTriggered: switchAccount()
	},
	Kirigami.Action {
	objectName: 'hard-logout'
	text: l10n.get('global-drawer-action-hard-logout')
	onTriggered: hardLogout()
	},
	Kirigami.Action {
	objectName: 'save'
	text: l10n.get('global-drawer-action-save-session')
	onTriggered: {
	recordLastSession()
	matrixSdk.serializeToFile()
	}
	},
	Kirigami.Action {
	objectName: 'configure-shortcuts'
	text: l10n.get('global-drawer-action-configure-shortcuts')
	onTriggered: {
	pushActionSettingsPage();
	}
	},
	Kirigami.Action {
	objectName: 'settings'
	text: l10n.get('global-drawer-action-settings')
	onTriggered: {
	pushSettingsPage();
	}
	},
	Kirigami.Action {
	objectName: 'create-room'
	enabled: root.loggedIn
	iconName: 'contact-new'
	text: l10n.get('global-drawer-action-create-room')
	onTriggered: {
	pushCreateRoomPage();
	}
	},
	Kirigami.Action {
	objectName: 'join-room'
	enabled: root.loggedIn
	text: l10n.get('global-drawer-action-join-room')
	onTriggered: {
	pushJoinRoomPage();
	}
	}
	]
	}

	contextDrawer: Kirigami.ContextDrawer {
	id: contextDrawer
	}

	property var actionCollection: KazvShortcuts.ActionCollection {
	id: globalActionCollection
	children: [
	root.globalDrawer,
	root.contextDrawer,
	]
	shortcutsConfig: kazvConfig
	}

	property var notifier: Kazv.Notifier {
	}

	pageStack.initialPage: Qt.resolvedUrl("LoginPage.qml")

	property var mainPage: Kazv.MainPage {
	id: mainPage
	}

	property var emptyPage: Kirigami.Page {
	title: l10n.get('empty-room-page-title')
	Controls.Label {
	text: l10n.get('empty-room-page-description')
	}
	}

	function activateRoomPage() {
	pageStack.push(Qt.resolvedUrl("RoomPage.qml"), {
	roomId: root.sdkVars.currentRoomId,
	});
	}

	function activateRoomSettingsPage(room) {
	pageStack.push(Qt.resolvedUrl("room-settings/RoomSettingsPage.qml"), {
	room
	});
	}

	function activateUserPage(user, room) {
	pageStack.push(Qt.resolvedUrl("qrc:///UserPage.qml"), {
	userId: user.userId,
	user,
	room
	});
	}

	function switchToMainPage() {
	pageStack.replace([mainPage])
	pageStack.currentIndex = 0
	}

	function switchToLoginPage() {
	pageStack.replace([Qt.resolvedUrl("LoginPage.qml")])
	pageStack.currentIndex = 0
	}

	function pushLoginPage() {
	pageStack.push(Qt.resolvedUrl("LoginPage.qml"), {
	isSwitchingAccount: true,
	});
	}

	function pushActionSettingsPage() {
	pageStack.push(Qt.resolvedUrl("ActionSettingsPage.qml"), {
	actions: globalActionCollection.allActions(),
	});
	}

	function pushSettingsPage() {
	pageStack.push(Qt.resolvedUrl("SettingsPage.qml"));
	}

	function pushCreateRoomPage() {
	pageStack.push(Qt.resolvedUrl("CreateRoomPage.qml"), {});
	}

	function pushJoinRoomPage() {
	pageStack.push(Qt.resolvedUrl("JoinRoomPage.qml"), {});
	}

	function sessionNameFor(userId, deviceId) {
	return userId + '/' + deviceId;
	}

	function loadSession(sessionName) {
	const succ = matrixSdk.loadSession(sessionName);

	if (succ) {
	console.log('load session successful');
	switchToMainPage();
	recordLastSession();
	} else {
	console.log('load session failed');
	}
	return succ;
	}

	function loadLastSession() {
	console.log('last session is:', kazvConfig.lastSession);

	return loadSession(kazvConfig.lastSession);
	}

	function recordLastSession() {
	kazvConfig.lastSession = sessionNameFor(matrixSdk.userId, matrixSdk.deviceId);
	}

	function reloadSdkVariables() {
	sdkVars.roomList = matrixSdk.roomList();
	sdkVars.currentRoomId = '';
	}

	Connections {
	target: sdkVars
	function onCurrentRoomIdChanged() {
	if (sdkVars.currentRoomId.length) {
	activateRoomPage()
	}
	}
	}

	function switchAccount() {
	pushLoginPage();
	}

	function hardLogout() {
	}

	Component.onCompleted: {
	actionCollection.setupShortcuts();
	loadLastSession();
	}

	onClosing: {
	kazvIOManager.clearJobs()
	}
	}

File Metadata

Mime Type: text/plain
Expires: Wed, May 14, 7:26 AM (1 d, 15 h)
Storage Engine: blob
Storage Format: Raw Data
Storage Handle: 92194
Default Alt Text: main.qml (6 KB)

main.qmlNo OneTemporaryActions

main.qmlView Options

File Metadata

Event Timeline

main.qml
No OneTemporary
Actions

main.qml
View Options